@ECHO OFF
REM Script:  EnableGroupPolicyEditorInWindows10HomeEdition.cmd
REM Version: 1.0
REM By:      Solomon Rutzky / Sql Quantum Leap
REM On:      2018-06-05
REM Post:    https://sqlquantumleap.com/2018/06/06/enable-group-policy-editor-gpedit-msc-on-windows-10-home-edition
REM Latest:  https://pastebin.com/jF8hG69a
REM
REM Usage:   EnableGroupPolicyEditorInWindows10HomeEdition [/F]
REM          /F = force execution when unable to verify running on Windows 10 Home Edition
 
TITLE Enable Group Policy Editor In Microsoft Windows 10 Home Edition
 
ECHO.
ECHO Verifying that we are running on Windows 10 Home Edition...
SYSTEMINFO | FINDSTR /O /C:"Microsoft Windows 10 Home"
 
IF %ERRORLEVEL% NEQ 0 (
    ECHO.
    SETLOCAL
    COLOR 0C
    ECHO    The current OS does not appear to be Windows 10 Home Edition!
    COLOR
 
    IF /I "%1"=="/F" (
        ECHO    Proceeding anyway due to "/F" switch passed in...
    ) ELSE (
        ECHO    Exiting...
        EXIT /B 1
    )
) ELSE (
    ECHO Yes. Proceeding...
)
 
ECHO.
 
PUSHD %SystemRoot%\servicing\Packages
REM CD /D %SystemRoot%\servicing\Packages
 
 
FOR %%F IN ("Microsoft-Windows-GroupPolicy-ClientTools-Package~*.mum") DO (
    DISM /Online /NoRestart /Add-Package:"%%F"
)
 
FOR %%F IN ("Microsoft-Windows-GroupPolicy-ClientExtensions-Package~*.mum") DO (
    DISM /Online /NoRestart /Add-Package:"%%F"
)
 
POPD
 
ECHO Done.